%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%% The Yi Syllable Font. Part III
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%% (c) Oliver Corff, Berlin/Beijing/Ulaanbaatar 1997.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%% This file contains 79 eyebrows.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  0,charwidth#,height#+2hp#,depth#);
	"The syllable MUOP";
	Z(lir,oben,8wp,0);
	Oh(8wp,9.5hp,rer,0.5hp);
	z1=(3wp,6.5hp);
	z2=(6.5wp,y1);
	z3=(x1,3.5hp);
	z4=(x2,y3);
	z5=(11wp,y1);
	z6=(x5,y3);
	getpen;
	draw z1--z2;
	draw z3--z4;
	draw z5--z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  1,charwidth#,height#+2hp#,depth#);
	"The syllable MOT";
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6hp);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
	z6=(7wp,8/24height);
	z7=(x6,1.75hp);
	draw z6--z7;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MO = 
	Huegel(lir,4hp,rer,0);
	z1=(hm,0);
	z2=(hm,oben);
	z3=(13wp,8hp);
	z4=(hm,7.75hp);
	z5=(12wp,1/2[y4,y6]);
	z6=(hm,5.25hp);
	getpen;
	draw z1--z2--z3;
	draw z4{right}..z5..{left}z6;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(  2,charwidth#,height#+2hp#,depth#);
	"The syllable MOX";
	eyebrow;
	MO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  3,charwidth#,height#+2hp#,depth#);
	"The syllable MO";
	MO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  4,charwidth#,height#+2hp#,depth#);
	"The syllable MOP";
	Sichel(lir,oben,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def ME = 
	Oh(9wp,7.5hp,rer,2.5hp);
	z1=(5.5wp,oben);
	z2=(x1,0);
	z3=(2wp,2hp);
	z4=(lir,vm);
	z6=(9wp,vm);
	getpen;
	draw z1--z2--z3;
	draw z4--z6;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(  5,charwidth#,height#+2hp#,depth#);
	"The syllable MEX";
	eyebrow;
	ME;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  6,charwidth#,height#+2hp#,depth#);
	"The syllable ME";
	ME;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  7,charwidth#,height#+2hp#,depth#);
	"The syllable MUT";
	II(lir,8hp,5.5wp,4.5hp);
	z1=(8.5wp,oben);
	z2=(x1,0);
	z3=(3wp,2hp);
	z4=(11wp,9hp);
	z5=(x1,1/2[y4,y6]);
	z6=(x4,1hp);
	% Zwei Hilfspunkte!
	z7=(lir,y4);
	z8=(lir,y6);
	getpen;
	draw z1--z2--z3;
	draw z4{z5-z7}..{left}z5&z5{right}..{z8-z5}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MU = 
	z1=(5wp,oben);
	z2=(x1,0);
	z3=(2wp,2hp);
	z4=(x1,vm);
	z6=(12wp,vm);
	z7=(x6,oben);
	z8=(x7,0);
	getpen;
	draw z1--z2--z3;
	draw z4--z6;
	draw z7--z8;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(  8,charwidth#,height#+2hp#,depth#);
	"The syllable MUX";
	eyebrow;
	MU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(  9,charwidth#,height#+2hp#,depth#);
	"The syllable MU";
	MU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 10,charwidth#,height#+2hp#,depth#);
	"The syllable MUP";
	Oh(lir,6hp,rer,3hp);
	z1=(3/4width,oben);
	z2=(hm,7.75hp);
	z3=(2wp,9hp);
	z4=(5wp,oben);
	z5=(x2,2/24height);
	z6=(3wp,3/24height);
	z7=(4wp,6hp);
	z8=(x7,3.5hp);
	z9=(x2,y7);
	z10=(x6,y7);
	z11=(x2,y8);
	z12=(x6,y8);
	getpen;
	draw z1..z2..z3..z4..z2---z5{down}..{z6-(hm,0)}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MUR = 
	z1=(9wp,oben);
	z2=(x1,0);
	z3=(3wp,2hp);
	z4=(5wp,8hp);
	z5=(x4,4hp);
	z6=(x1,y4);
	z7=(rer,y6);
	z8=(x1,2.5hp);
	z9=(x7,y8);
	getpen;
	draw z1--z2--z3;
	draw z4--z5;
	draw z6--z7;
	draw z8--z9;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 11,charwidth#,height#+2hp#,depth#);
	"The syllable MURX";
	eyebrow;
	MUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 12,charwidth#,height#+2hp#,depth#);
	"The syllable MUR";
	MUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 13,charwidth#,height#+2hp#,depth#);
	"The syllable MYT";
	z1=(11wp,oben);
	z2=(x1,8hp);
	z3=(2wp,9hp);
	z4=(x3,0);
	z5=(lir,7hp);
	z6=(11wp,1/2[y5,y7]);
	z7=(x5,1hp);
	z8=(rer,y5);
	z9=(5wp,y6);
	z10=(x8,y7);
	getpen;
	draw z1--z2--z3--z4;
	draw z5{right}..z6..{left}z7;
	draw z8{left}..z9..{right}z10;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MY = 
	Liane(lir,oben,rer,vm);
	II(3wp,4hp,13wp,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 14,charwidth#,height#+2hp#,depth#);
	"The syllable MYX";
	eyebrow;
	MY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 15,charwidth#,height#+2hp#,depth#);
	"The syllable MY";
	MY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 16,charwidth#,height#+2hp#,depth#);
	"The syllable MYP";
	z1=(5wp,oben);
	z2=(x1,0);
	z3=(lir,vm);
	z4=(rer,y3);
	z5=(11wp,9hp);
	z6=(x5,6.5hp);
	z7=(x5,3.5hp);
	z8=(x5,1hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
	draw z5--z6;
	draw z7--z8;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGIE = 
	z1=(rer,8hp);
	z2=(11.5wp,oben);
	z3=(x2,0);
	z4=(x2,y1);
	z5=(6.5wp,oben);
	z6=(x5,0);
	z7=(x5,9hp);
	z8=(lir,1/2[y7,y9]);
	z9=(x5,1/2[y7,0]);
	z10=(lir,1/2[y9,0]);
	getpen;
	draw z1--z2--z3;
	draw z4--z5--z6;
	draw z7..z8..z9&z9..z10..z6;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 17,charwidth#,height#+2hp#,depth#);
	"The syllable MGIEX";
	eyebrow;
	MGIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 18,charwidth#,height#+2hp#,depth#);
	"The syllable MGIE";
	MGIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 19,charwidth#,height#+2hp#,depth#);
	"The syllable MGAT";
	Oh(1/4width,oben,rer,0);
	Ih(10/32width,7hp,26/32width,7hp);
	Ih(lir,1.5hp,7wp,3.5hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGA = 
	x2=x3=lir+1wp;
	y2=y6=0; y3=y7=oben;
	x4=x9=x10=1/2[x2,x6];
	x6=x7=11wp;
	x5=x6-2.5/8width;
	y5=2hp;
	y4=y3-1.5hp;
	x8=14wp; y8=y7-1.5hp;
	y9=y11=y12=5hp;
	y10=0hp;
	x11=x2; x12=x6;
	getpen;
	draw z2--z3--z4;
	draw z6--z7--z8;
	draw z9--z10;
	draw z11--z12;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 20,charwidth#,height#+2hp#,depth#);
	"The syllable MGAX";
	eyebrow;
	MGA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 21,charwidth#,height#+2hp#,depth#);
	"The syllable MGA";
	MGA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 22,charwidth#,height#+2hp#,depth#);
	"The syllable MGAP";
	z1=(7.5wp,oben);
	z2=(x1,2hp);
	z3=(3wp,4hp);
	z4=(x3,0);
	z5=(x1,7hp);
	z6=(10wp,y5);
	z7=(13wp,oben);
	z8=(x7,4hp);
	getpen;
	draw z1--z2--z3--z4; draw z5--z6;
	draw z7..z6..z8;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGUO = 
	Oh(lir,9hp,rer,6.25hp);
	Oh(lir,3.75hp,rer,1hp);
	II(3wp,5.5hp,13wp,4.5hp);
	z1=(hm,oben);
	z2=(x1,0);
	getpen;
	draw z1--z2;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 23,charwidth#,height#+2hp#,depth#);
	"The syllable MGUOX";
	eyebrow;
	MGUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 24,charwidth#,height#+2hp#,depth#);
	"The syllable MGUO";
	MGUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 25,charwidth#,height#+2hp#,depth#);
	"The syllable MGUOP";
	Oh(3wp,oben,13wp,5.5hp);
	Huegel(lir,3.5hp,rer,0);
	Ih(hm,5.5hp,hm,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 26,charwidth#,height#+2hp#,depth#);
	"The syllable MGOT";
	Plus(3wp,oben,13wp,5.5hp);
	Oh(3wp,oben,13wp,5.5hp);
	Huegel(lir,3.5hp,rer,0);
	Ih(hm,5.5hp,hm,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGO = 
	Oh(4wp,oben,rer,6.75hp);
	Huegel(lir,3.25hp,rer,0);
	z1=(9.75wp,6.75hp);
	z2=(x1,4.75hp);
	z3=(7.5wp,5.25hp);
	z4=(x3,0);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 27,charwidth#,height#+2hp#,depth#);
	"The syllable MGOX";
	eyebrow;
	MGO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 28,charwidth#,height#+2hp#,depth#);
	"The syllable MGO";
	MGO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 29,charwidth#,height#+2hp#,depth#);
	"The syllable MGOP";
	Ih(lir,vm,7wp,vm);
	z1=(rer,oben);
	z2=(9wp,1/2[y1,y3]);
	z3=(rer,vm);
	z4=(x2,1/2[y5,y3]);
	z5=(rer,0);
	z6=(4.5wp,vm);
	getpen;
	draw z1..z2..z3&z3..z4..z5;
	draw z2..z6..z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGE = 
	Ih(13wp,8.5hp,13wp,7hp);
	Ih(13wp,1.5hp,13wp,3hp);
	Ih(6wp,6hp,6wp,4hp);
	z1=(rer,oben);
	z2=(8.5wp,1/2[y1,y3]);
	z3=(x1,5.5hp);
	z4=(x1,4.5hp);
	z5=(x2,1/2[y4,y6]);
	z6=(x1,0);
	z7=(7wp,y2);
	z8=(lir,vm);
	z9=(x7,y5);
	getpen;
	draw z1..tension 1.2..z2..tension 1.2..z3;
	draw z4..tension 1.2..z5..tension 1.2..z6; draw z7..z8..z9;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 30,charwidth#,height#+2hp#,depth#);
	"The syllable MGEX";
	eyebrow;
	MGE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 31,charwidth#,height#+2hp#,depth#);
	"The syllable MGE";
	MGE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 32,charwidth#,height#+2hp#,depth#);
	"The syllable MGEP";
	Oh(lir,oben,11wp,0);
	Ih(11wp,vm,rer,vm);
	z1=(rer,oben);
	z2=(7wp,vm);
	z3=(rer,0);
	getpen;
	draw z1..z2..z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 33,charwidth#,height#+2hp#,depth#);
	"The syllable MGUT";
	U(4.5wp,oben,11.5wp,0);
	Liane(6wp,9hp,10wp,7hp);
	Liane(6wp,5hp,10wp,3hp);
	z1=(lir,9hp);
	z2=(1/4width,1/2[y1,y3]);
	z3=(lir,2hp);
	z4=(rer,y1);
	z5=(3/4width,y2);
	z6=(rer,y3);
	getpen;
	draw z1..z2..z3;
	draw z4..z5..z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGU = 
	Ih(3wp,9hp,rer,7hp);
	Ih(lir,vm,rer,vm);
	Ih(3wp,1hp,rer,3hp);
	z1=(rer,oben);
	z2=(7wp,vm);
	z3=(rer,0);
	getpen;
	draw z1..z2..z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 34,charwidth#,height#+2hp#,depth#);
	"The syllable MGUX";
	eyebrow;
	MGU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 35,charwidth#,height#+2hp#,depth#);
	"The syllable MGU";
	MGU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 36,charwidth#,height#+2hp#,depth#);
	"The syllable MGUP";
	Liane(lir,oben,rer,6hp);
	Er(3wp,4.5hp,13wp,3hp);
	z1=(hm,6hp);
	z2=(hm,1.5hp);
	z3=(lir,y2);
	getpen;
	draw z1---z2{down}..{up}z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def MGUR = 
	U(lir,oben,rer,0);
	Blitz(6wp,oben,10wp,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 37,charwidth#,height#+2hp#,depth#);
	"The syllable MGURX";
	eyebrow;
	MGUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 38,charwidth#,height#+2hp#,depth#);
	"The syllable MGUR";
	MGUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 39,charwidth#,height#+2hp#,depth#);
	"The syllable NIT";
	Ddash(lir,7hp,lir,0);
	Ddash(rer,7hp,rer,0);
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,0);
	z4=(4wp,1/2[y5,0]);
	z5=(x2,6.5hp);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NI = 
	H(8.5wp,oben,13wp,0);
	Ih(5.5wp,1.5hp,8.5wp,0);
	II(2.5wp,9hp,6.5wp,5.75hp);
	Ih(lir,4.5hp,6.75wp,4.5hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 40,charwidth#,height#+2hp#,depth#);
	"The syllable NIX";
	eyebrow;
	NI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 41,charwidth#,height#+2hp#,depth#);
	"The syllable NI";
	NI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 42,charwidth#,height#+2hp#,depth#);
	"The syllable NIP";
	Ih(6/32width,2hp,rer,6.5hp);
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(10wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6.5hp);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NIE = 
	Oh(6.5wp,oben,rer,0);
	z1=(lir,3hp);
	z2=(4wp,2hp);
	z3=(x2,6.5hp);
	z4=(rer,4.5hp);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 43,charwidth#,height#+2hp#,depth#);
	"The syllable NIEX";
	eyebrow;
	NIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 44,charwidth#,height#+2hp#,depth#);
	"The syllable NIE";
	NIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 45,charwidth#,height#+2hp#,depth#);
	"The syllable NIEP";
	Z(1/4width,oben,3/4width,0);
	Ih(hm,3.5hp,rer,6.5hp);
	z1=(hm,6.5hp);
	z2=(rer,1/2[y1,y3]);
	z3=(hm,2hp);
	getpen;
	draw z1{right}..z2..{left}z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NA = 
	Ih(8wp,4.5hp,rer,4.5hp);
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,2.25hp);
	z4=(5.75wp,3.5hp);
	z5=(x4,0);
	z6=(lir,6hp);
	z7=(5wp,5hp);
	z8=(x7,8.5hp);
	z9=(rer,6.5hp);
	getpen;
	draw z1--z2--z3--z4--z5;
	draw z6--z7--z8--z9;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 46,charwidth#,height#+2hp#,depth#);
	"The syllable NAX";
	eyebrow;
	NA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 47,charwidth#,height#+2hp#,depth#);
	"The syllable NA";
	NA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 48,charwidth#,height#+2hp#,depth#);
	"The syllable NAP";
	z4=(rer,8.5hp);
	z5=(9.5wp,oben);
	z6=(x5,1.25hp);
	z7=(1/4width,2.5hp);
	z8=(x7,0);
	z9=(5wp,7hp);
	z10=(rer,y9);
	z11=(x9,4.5hp);
	z12=(rer,y11);
	z13=(3wp,7.5hp);
	z14=(x13,4hp);
	getpen;
	draw z4--z5--z6--z7--z8;
	draw z9--z10;
	draw z11--z12;
	draw z13--z14;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NUO = 
	Z(3wp,oben,14wp,0);
	z1=(lir,oben);
	z2=(hm,1/2[y1,y3]);
	z3=(lir,5.5hp);
	getpen;
	draw z1{right}..z2..{left}z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 49,charwidth#,height#+2hp#,depth#);
	"The syllable NUOX";
	eyebrow;
	NUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 50,charwidth#,height#+2hp#,depth#);
	"The syllable NUO";
	NUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 51,charwidth#,height#+2hp#,depth#);
	"The syllable NUOP";
	Ih(lir,oben,lir,0);
	Oh(5wp,oben,rer,0);
	Ih(9.5wp,6hp,9.5wp,4hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 52,charwidth#,height#+2hp#,depth#);
	"The syllable NOT";
	Oh(lir,oben,11wp,0);
	Er(5/32width,6.75hp,rer,3.25hp);
	Ih(rer,9hp,rer,1hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NO = 
	Plus(lir,8.75hp,9wp,5.75hp);
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,2.25hp);
	z4=(5wp,3.5hp);
	z5=(x4,0);
	z6=(lir,8.75hp);
	z7=(5.5wp,9.75hp);
	z8=(9wp,y6);
	z10=(lir,5.75hp);
	z11=(x7,4.75hp);
	z12=(x8,y10);
	getpen;
	draw z1--z2--z3--z4--z5;
	draw z6..z7..z8;
	draw z10..z11..z12;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 53,charwidth#,height#+2hp#,depth#);
	"The syllable NOX";
	eyebrow;
	NO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 54,charwidth#,height#+2hp#,depth#);
	"The syllable NO";
	NO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 55,charwidth#,height#+2hp#,depth#);
	"The syllable NOP";
	Liane(lir,9.75hp,8.5wp,7.75hp);
	Liane(lir,7hp,8.5wp,5hp);
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,2.25hp);
	z4=(5wp,3.5hp);
	z5=(x4,0);
	getpen;
	draw z1--z2--z3--z4--z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NE = 
	Z(5wp,oben,14wp,0);
	Ih(4wp,8hp,9.5wp,6hp);
	Ih(4wp,5hp,9.5wp,3hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 56,charwidth#,height#+2hp#,depth#);
	"The syllable NEX";
	eyebrow;
	NE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 57,charwidth#,height#+2hp#,depth#);
	"The syllable NE";
	NE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 58,charwidth#,height#+2hp#,depth#);
	"The syllable NEP";
	Ih(4wp,9hp,10.5wp,7hp);
	Ih(4wp,6.75hp,10.5wp,4.75hp);
	z1=(rer,8.5hp);
	z2=(10.5wp,oben);
	z3=(x2,2.25hp);
	z4=(5wp,3.5hp);
	z5=(x4,0);
	getpen;
	draw z1--z2--z3--z4--z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 59,charwidth#,height#+2hp#,depth#);
	"The syllable NUT";
	II(3wp,8hp,6.5wp,5hp);
	Z(5wp,oben,14wp,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NU = 
	Z(5.5wp,oben,14wp,0);
	Liane(lir,oben,7wp,8.5hp);
	Liane(lir,7.5hp,7wp,6hp);
	Liane(lir,5hp,7wp,3.5hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 60,charwidth#,height#+2hp#,depth#);
	"The syllable NUX";
	eyebrow;
	NU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 61,charwidth#,height#+2hp#,depth#);
	"The syllable NU";
	NU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 62,charwidth#,height#+2hp#,depth#);
	"The syllable NUP";
	II(3wp,8.5hp,6.5wp,6hp);
	Z(5wp,oben,14wp,0);
	z1=(lir,5.25hp);
	z2=(1/2[x1,x3],4.5hp);
	z3=(7.5wp,y1);
	getpen;
	draw z1..z2..z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NUR = 
	II(3wp,8.5hp,6.5wp,6hp);
	ZPimmel(5wp,oben,13.5wp,0);
	z1=(lir,4.75hp);
	z3=(6.75wp,y1);
	getpen;
	draw z1--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 63,charwidth#,height#+2hp#,depth#);
	"The syllable NURX";
	eyebrow;
	NUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 64,charwidth#,height#+2hp#,depth#);
	"The syllable NUR";
	NUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 65,charwidth#,height#+2hp#,depth#);
	"The syllable NBIT";
	II(9wp,6.5hp,13wp,2hp);
	Ih(5wp,4.5hp,13wp,4.5hp);
	Ddash(lir,9hp,lir,1.25hp);
	z1=(rer,8hp);
	z2=(5wp,oben);
	z3=(x2,0);
	getpen;
	draw z1--z2--z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBI = 
	Oh(lir,oben,rer,3.75hp);
	Plus(lir,oben,rer,3.75hp);
	Ih(11wp,3hp,11wp,2hp);
	z1=(hm,3.75hp);
	z2=(hm,2hp);
	z3=(1/3[x2,x4],0);
	z4=(rer,1.25hp);
	getpen;
	draw z1--z2{down}..z3..z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 66,charwidth#,height#+2hp#,depth#);
	"The syllable NBIX";
	eyebrow;
	NBI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 67,charwidth#,height#+2hp#,depth#);
	"The syllable NBI";
	NBI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 68,charwidth#,height#+2hp#,depth#);
	"The syllable NBIP";
	Er(6wp,5hp,13wp,2.5hp);
	z1=(rer,8.5hp);
	z2=(9.5wp,oben);
	z3=(x2,0);
	z4=(x2,y1);
	z5=(3wp,oben);
	z6=(x5,0);
	getpen;
	draw z1--z2--z3; draw z4--z5--z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBIE = 
	Er(lir,6.75hp,11wp,3.25hp);
	Ih(7wp,oben,7wp,0);
	z1=(lir,oben);
	z2=(11.5wp,oben);
	z3=(rer,7hp);
	getpen;
	draw z1--z2--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 69,charwidth#,height#+2hp#,depth#);
	"The syllable NBIEX";
	eyebrow;
	NBIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 70,charwidth#,height#+2hp#,depth#);
	"The syllable NBIE";
	NBIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 71,charwidth#,height#+2hp#,depth#);
	"The syllable NBIEP";
	Er(lir,7.25hp,rer,2.75hp);
	Ih(hm,oben,hm,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 72,charwidth#,height#+2hp#,depth#);
	"The syllable NBAT";
	Arsch(lir,oben,10wp,0);
	z1=(10wp,vm);
	z2=(rer,y1);
	z3=(1/2[x1,x2],7.75hp);
	z4=(x3,6.25hp);
	z5=(x3,3.75hp);
	z6=(x3,2.25hp);
	z7=(rer,8hp);
	z8=(rer,2hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
	draw z5--z6;
	draw z7--z8;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBA = 
	Er(lir,7.75hp,rer,2.25hp);
	X(lir,oben,rer,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 73,charwidth#,height#+2hp#,depth#);
	"The syllable NBAX";
	eyebrow;
	NBA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 74,charwidth#,height#+2hp#,depth#);
	"The syllable NBA";
	NBA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 75,charwidth#,height#+2hp#,depth#);
	"The syllable NBAP";
	X(4wp,9hp,12wp,1hp);
	II(lir,oben,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 76,charwidth#,height#+2hp#,depth#);
	"The syllable NBOT";
	Ih(3/4width,6.5hp,3/4width,3.5hp);
	z1=(rer,oben);
	z2=(rer,7.5hp);
	z3=(6wp,9hp);
	z4=(6wp,1hp);
	z5=(rer,2.5hp);
	z6=(rer,0);
	z7=(lir,4hp);
	z8=(3wp,5.5hp);
	z9=(x3,7hp);
	getpen;
	draw z1--z2--z3--z4--z5--z6;
	draw z7..z8..z9;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBO = 
	Busen(lir,oben,rer,6hp);
	Plus(4wp,5.5hp,12wp,1.5hp);
	Liane(lir,2hp,rer,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 77,charwidth#,height#+2hp#,depth#);
	"The syllable NBOX";
	eyebrow;
	NBO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 78,charwidth#,height#+2hp#,depth#);
	"The syllable NBO";
	NBO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 79,charwidth#,height#+2hp#,depth#);
	"The syllable NBOP";
	Busen(lir,oben,rer,6hp);
	Ih(8wp,5hp,8wp,2hp);
	Liane(lir,2hp,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 80,charwidth#,height#+2hp#,depth#);
	"The syllable NBUT";
	Ih(9wp,0,9wp,8.5hp);
	Ih(9wp,4.75hp,rer,4.75hp);
	% "Grosses C"
	z1=(rer,1.5hp);
	z2=(hm,0);
	z3=(lir,1/2[y1,y5]);
	z4=(hm,8.5hp);
	z5=(rer,7.75hp);
	z6=(rer,oben);
	getpen;
	draw z1..z2..z3..z4..z5--z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBU = 
	Ih(1/4width,oben,1/4width,8hp);
	Ih(1/4width,0,1/4width,2hp);
	Otense(7.5wp,oben,rer,0,1.25);
	z1=(7.5wp,6.5hp);
	z2=(lir,1/2[y1,y3]);
	z3=(x1,3.5hp);
	getpen;
	draw z1{left}..z2..{right}z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 81,charwidth#,height#+2hp#,depth#);
	"The syllable NBUX";
	eyebrow;
	NBU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 82,charwidth#,height#+2hp#,depth#);
	"The syllable NBU";
	NBU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 83,charwidth#,height#+2hp#,depth#);
	"The syllable NBUP";
	Ih(hm,oben,hm,0);
	Oh(lir,8hp,rer,2hp);
	Ih(10.75wp,5.75hp,10.75wp,4.25hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBUR = 
	Otense(lir,oben,6.25wp,0,2);
	Otense(9.75wp,oben,rer,0,2);
	Ih(6.25wp,vm,9.75wp,vm);
	Ih(hm,9.5hp,hm,8.25hp);
	Ih(hm,0.5hp,hm,1.75hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 84,charwidth#,height#+2hp#,depth#);
	"The syllable NBURX";
	eyebrow;
	NBUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 85,charwidth#,height#+2hp#,depth#);
	"The syllable NBUR";
	NBUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 86,charwidth#,height#+2hp#,depth#);
	"The syllable NBYT";
	Oh(lir,oben,11wp,0);
	Ih(7wp,vm,rer,vm);
	Ih(rer,8.5hp,rer,6.5hp);
	Ih(rer,3.5hp,rer,1.5hp);
	z1=(rer,oben);
	z2=(7wp,vm);
	z3=(rer,0);
	getpen;
	draw z1..z2..z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBY = 
	U(lir,oben,rer,0);
	Ih(hm,oben,hm,0);
	Ih(lir,5.5hp,hm,5.5hp);
	Tdash(11wp,9hp,2hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 87,charwidth#,height#+2hp#,depth#);
	"The syllable NBYX";
	eyebrow;
	NBY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 88,charwidth#,height#+2hp#,depth#);
	"The syllable NBY";
	NBY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 89,charwidth#,height#+2hp#,depth#);
	"The syllable NBYP";
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,2.25hp);
	z4=(5wp,3.5hp);
	z5=(x4,0);
	z6=(9wp,oben);
	z7=(6.5wp,1/2[y6,y8]);
	z8=(x6,1/2[y6,y10]);
	z9=(x7,1/2[y8,y10]);
	z10=(x6,4hp);
	z11=(lir,9hp);
	z12=(4.75wp,1/2[y11,y13]);
	z13=(x11,5hp);
	getpen;
	draw z1--z2--z3--z4--z5;
	draw z6..z7..z8&z8..z9..z10;
	draw z11..z12..z13;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NBYR = 
	IXI(3wp,8.5hp,13wp,1.5hp);
	Ih(8wp,oben,8wp,0);
	Ih(3wp,vm,13wp,vm);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 90,charwidth#,height#+2hp#,depth#);
	"The syllable NBYRX";
	eyebrow;
	NBYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 91,charwidth#,height#+2hp#,depth#);
	"The syllable NBYR";
	NBYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 92,charwidth#,height#+2hp#,depth#);
	"The syllable NDIT";
	Ih(hm,oben,hm,7.5hp);
	N(lir,7hp,rer,3.5hp);
	III(1/4width,2.5hp,3/4width,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDI = 
	Ih(4wp,oben,4wp,6.5hp);
	Ih(4wp,8.25hp,12wp,8.25hp);
	Ih(4wp,4.75hp,4wp,1.25hp);
	z1=(12wp,oben);
	z2=(x1,0);
	z3=(4wp,3hp);
	getpen;
	draw z1--z2--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 93,charwidth#,height#+2hp#,depth#);
	"The syllable NDIX";
	eyebrow;
	NDI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 94,charwidth#,height#+2hp#,depth#);
	"The syllable NDI";
	NDI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 95,charwidth#,height#+2hp#,depth#);
	"The syllable NDIP";
	Arsch(lir,oben,rer,0);
	z1=(hm,7hp);
	z2=(hm,4.75hp);
	getpen;
	draw z1--z2;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDIE = 
	Z(1/4width,oben,3/4width,0);
	Er(6wp,6hp,10wp,4hp);
	z1=(3wp,7hp);
	z2=(4.5wp,vm);
	z3=(x1,3hp);
	z4=(13wp,y1);
	z5=(11.5wp,vm);
	z6=(x4,y3);
	getpen;
	draw z1..z2..z3; draw z4..z5..z6;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 96,charwidth#,height#+2hp#,depth#);
	"The syllable NDIEX";
	eyebrow;
	NDIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 97,charwidth#,height#+2hp#,depth#);
	"The syllable NDIE";
	NDIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar( 98,charwidth#,height#+2hp#,depth#);
	"The syllable NDAT";
	Oh(lir,oben,7.5wp,6hp);
	Ih(7.5wp,8hp,11wp,8hp);
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,2hp);
	z4=(5wp,3.25hp);
	z5=(x4,0);
	getpen;
	draw z1--z2--z3--z4--z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDA = 
	Oh(lir,oben,7.5wp,6.75hp);
	Ih(4wp,5.5hp,14wp,5.5hp);
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,2hp);
	z4=(5wp,3.25hp);
	z5=(x4,0);
	getpen;
	draw z1--z2--z3--z4--z5;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar( 99,charwidth#,height#+2hp#,depth#);
	"The syllable NDAX";
	eyebrow;
	NDA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(100,charwidth#,height#+2hp#,depth#);
	"The syllable NDA";
	NDA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(101,charwidth#,height#+2hp#,depth#);
	"The syllable NDAP";
	Oh(lir,9hp,6wp,5hp);
	z1=(8wp,oben);
	z2=(x1,0);
	z3=(lir,2hp);
	z4=(11wp,9.5hp);
	z5=(x4,y3);
	z6=(14wp,y4);
	z7=(x6,6.5hp);
	z8=(x5,4.5hp);
	z9=(x1,y8);
	getpen;
	draw z1--z2--z3;
	draw z4--z5;
	draw z6--z7{down}..{left}z8--z9;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(102,charwidth#,height#+2hp#,depth#);
	"The syllable NDOT";
	Ih(lir,7hp,rer,7hp);
	z1=(8.5wp,oben);
	z2=(x1,2.75hp);
	z3=(4wp,3.75hp);
	z4=(x3,0);
	z5=(rer,9hp);
	z6=(lir,1/2[y5,y7]);
	z7=(rer,5hp);
	getpen;
	draw z1--z2--z3--z4;
	draw z5{left}..tension 1.2..z6..tension 1.2..{right}z7;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDO = 
	Oh(5wp,9hp,9wp,6hp);
	z1=(11.5wp,oben);
	z2=(x1,2.5hp);
	z3=(5wp,3.75hp);
	z4=(x3,0);
	z5=(4.5wp,10hp);
	z6=(2.5wp,1/2[y5,y7]);
	z7=(3wp,6hp);
	getpen;
	draw z1--z2--z3--z4;
	draw z5..tension 1.2..z6..tension 1.2..z7;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(103,charwidth#,height#+2hp#,depth#);
	"The syllable NDOX";
	eyebrow;
	NDO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(104,charwidth#,height#+2hp#,depth#);
	"The syllable NDO";
	NDO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(105,charwidth#,height#+2hp#,depth#);
	"The syllable NDOP";
	Smiley(5wp,8.75hp,9wp,5hp);
	z1=(11.5wp,oben);
	z2=(x1,2.5hp);
	z3=(5wp,3.75hp);
	z4=(x3,0);
	z5=(4.5wp,10hp);
	z6=(2.5wp,1/2[y5,y7]);
	z7=(3wp,6hp);
	getpen;
	draw z1--z2--z3--z4;
	draw z5..tension 1.2..z6..tension 1.2..z7;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDE = 
	Oh(lir,oben,6wp,6.5hp);
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6hp);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(106,charwidth#,height#+2hp#,depth#);
	"The syllable NDEX";
	eyebrow;
	NDE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(107,charwidth#,height#+2hp#,depth#);
	"The syllable NDE";
	NDE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(108,charwidth#,height#+2hp#,depth#);
	"The syllable NDEP";
	Z(5wp,oben,13wp,0);
	Oh(4wp,oben,7wp,7.25hp);
	z1=(lir,9hp);
	z2=(3.5wp,6.5hp);
	z3=(9wp,5hp);
	getpen;
	draw z1..z2..z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(109,charwidth#,height#+2hp#,depth#);
	"The syllable NDUT";
	X(lir,oben,13wp,0);
	z1=(hm,vm);
	z2=(rer,vm);
	z3=(rer,7.25hp);
	z4=(rer,2.75hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDU = 
	z1=(lir,2hp);
	z2=(hm,0);
	z3=(rer,y1);
	z4=(8wp,10hp);
	z5=(x4,0);
	z6=(12wp,9.5hp);
	z7=(x6,6hp);
	z8=(x5,4hp);
	z9=(x4,y8);
	getpen;
	draw z1..z2..z3;
	draw z4--z5;
	draw z6--z7{down}..{left}z8--z9;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(110,charwidth#,height#+2hp#,depth#);
	"The syllable NDUX";
	eyebrow;
	NDU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(111,charwidth#,height#+2hp#,depth#);
	"The syllable NDU";
	NDU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(112,charwidth#,height#+2hp#,depth#);
	"The syllable NDUP";
	Oh(lir,oben,rer,6hp);
	Er(lir,4hp,rer,2hp);
	Ih(hm,6hp,hm,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NDUR = 
	Oh(lir,oben,rer,6hp);
	Er(lir,4hp,hm,2hp);
	Ih(hm,6hp,hm,0);
	Ih(3/4width,4hp,3/4width,2hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(113,charwidth#,height#+2hp#,depth#);
	"The syllable NDURX";
	eyebrow;
	NDUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(114,charwidth#,height#+2hp#,depth#);
	"The syllable NDUR";
	NDUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NGIE = 
	Z(3wp,oben,13wp,3hp);
	Busen(lir,2.5hp,rer,0);
	Ih(1/4width,8.5hp,1/4width,6.5hp);
	Ih(3/4width,6.75hp,3/4width,4.75hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(115,charwidth#,height#+2hp#,depth#);
	"The syllable NGIEX";
	eyebrow;
	NGIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(116,charwidth#,height#+2hp#,depth#);
	"The syllable NGIE";
	NGIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(117,charwidth#,height#+2hp#,depth#);
	"The syllable NGIEP";
	Z(1/4width,oben,3/4width,0);
	Plus(lir,7hp,6.25wp,3hp);
	Plus(9.75wp,7hp,rer,3hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(118,charwidth#,height#+2hp#,depth#);
	"The syllable NGAT";
	U(lir,oben,11wp,0);
	z1=(lir,6hp);
	z2=(11wp,5hp);
	z3=(rer,6hp);
	z4=(rer,9hp);
	getpen;
	draw z1--z2{right}..{up}z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NGA = 
	N(3wp,oben,rer,5.75hp);
	z1=(8.5wp,oben);
	z2=(x1,2hp);
	z3=(5.5wp,3.5hp);
	z4=(x3,0);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(119,charwidth#,height#+2hp#,depth#);
	"The syllable NGAX";
	eyebrow;
	NGA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(120,charwidth#,height#+2hp#,depth#);
	"The syllable NGA";
	NGA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(121,charwidth#,height#+2hp#,depth#);
	"The syllable NGAP";
	Plus(lir,9hp,7.5wp,4hp);
	z1=(9wp,oben);
	z2=(x1,0);
	z3=(3wp,2hp);
	z4=(x1,7.5hp);
	z5=(rer,1/2[y4,y6]);
	z6=(x4,2.5hp);
	getpen;
	draw z1--z2--z3;
	draw z4{right}..z5..{left}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(122,charwidth#,height#+2hp#,depth#);
	"The syllable NGUOT";
	Huegel(lir,oben,rer,8hp);
	X(1/4width,7.5hp,3/4width,2.5hp);
	Liane(lir,2hp,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NGUO = 
	Huegel(4.5wp,oben,11.5wp,7hp);
	Ih(hm,9hp,hm,8hp);
	z1=(lir,0);
	z2=(13wp,7hp);
	z3=(3wp,y2);
	z4=(rer,0);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(123,charwidth#,height#+2hp#,depth#);
	"The syllable NGUOX";
	eyebrow;
	NGUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(124,charwidth#,height#+2hp#,depth#);
	"The syllable NGUO";
	NGUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(125,charwidth#,height#+2hp#,depth#);
	"The syllable NGOT";
	z1=(lir,oben);
	z2=(hm,vm);
	z3=(lir,0);
	z4=(rer,oben);
	z5=(rer,0);
	getpen;
	draw z1..z2..z3;
	draw z4..z2..z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NGO = 
	Huegel(4wp,oben,12wp,6.5hp);
	Oh(lir,7hp,rer,0);
	Ih(hm,4.5hp,hm,2.5hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(126,charwidth#,height#+2hp#,depth#);
	"The syllable NGOX";
	eyebrow;
	NGO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(127,charwidth#,height#+2hp#,depth#);
	"The syllable NGO";
	NGO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(128,charwidth#,height#+2hp#,depth#);
	"The syllable NGOP";
	z1=(hm,oben);
	z2=(hm,0);
	z3=(lir,2hp);
	z4=(6wp,8hp);
	z5=(x4,5.5hp);
	z6=(4.5wp,5hp);
	z7=(3wp,5.75hp);
	z8=(rer,9hp);
	z9=(x1,6hp);
	z10=(13wp,1/2[y9,y11]);
	z11=(x1,2hp);
	getpen;
	draw z1--z2--z3;
	draw z4---z5{down}..z6---z7;
	draw z8--z9&z9..z10..z11;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NGE = 
	Plus(lir,oben,10wp,3.5hp);
	z1=(12wp,oben);
	z2=(x1,0);
	z3=(2wp,2hp);
	z4=(x1,vm);
	z6=(12wp,vm);
	z7=(x6,oben);
	z8=(x7,0);
	getpen;
	draw z1--z2--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(129,charwidth#,height#+2hp#,depth#);
	"The syllable NGEX";
	eyebrow;
	NGE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(130,charwidth#,height#+2hp#,depth#);
	"The syllable NGE";
	NGE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(131,charwidth#,height#+2hp#,depth#);
	"The syllable NGEP";
	Oh(lir,oben,4.5/8width,0);
	Oh(5.25/8width,7hp,rer,3hp);
	Ih(lir,7hp,4.25/8width,7hp);
	Ih(lir,5hp,5.25/8width,5hp);
	Ih(lir,3hp,4.25/8width,3hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(132,charwidth#,height#+2hp#,depth#);
	"The syllable NZIT";
	z1=(1/4width,oben);
	z2=(13wp,y1);
	z3=(8.5wp,oben);
	z4=(x3,8.5hp);
	z5=(lir,2hp);
	z6=(7wp,0);
	z7=(x6,8.75hp);
	z8=(rer,7hp);
	z9=(12wp,5.5hp);
	z10=(x9,2hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
	draw z5--z6--z7--z8;
	draw z9--z10;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZI = 
	Quad(1/4width,oben,3/4width,0);
	Ih(lir,vm,rer,vm);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(133,charwidth#,height#+2hp#,depth#);
	"The syllable NZIX";
	eyebrow;
	NZI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(134,charwidth#,height#+2hp#,depth#);
	"The syllable NZI";
	NZI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(135,charwidth#,height#+2hp#,depth#);
	"The syllable NZIP";
	Ih(4wp,9hp,4wp,6hp);
	Ih(4wp,4hp,4wp,1hp);
	x10=x11=x13=4/8width;
	y10=oben;
	y11=0;
	x12=x14=6/8width;
	y12=9hp;
	y14=1hp;
	y13=1/2[y12,y14];
	y20=y21=0;
	x20=0; x21=1;
	getpen;
	draw z10--z11;
	draw z12..{z20-z21}z13&z13{z21-z20}..z14;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZIE = 
	U(lir,oben,9.5wp,0);
	Ih(lir,5hp,9.5wp,5hp);
	Ih(5.75wp,8.5hp,5.75wp,6.5hp);
	Ih(5.75wp,3.5hp,5.75wp,1.5hp);
	z4=(12wp,9hp);
	z5=(9.75wp,1/2[y4,y6]);
	z6=(x4,1hp);
	% Zwei Hilfspunkte!
	z7=(lir,y4);
	z8=(lir,y6);
	getpen;
	draw z4{z5-z7}..{left}z5&z5{right}..{z8-z5}z6;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(136,charwidth#,height#+2hp#,depth#);
	"The syllable NZIEX";
	eyebrow;
	NZIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(137,charwidth#,height#+2hp#,depth#);
	"The syllable NZIE";
	NZIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(138,charwidth#,height#+2hp#,depth#);
	"The syllable NZIEP";
	U(lir,oben,9.5wp,0);
	z4=(12wp,9hp);
	z5=(9.75wp,1/2[y4,y6]);
	z6=(x4,1hp);
	% Zwei Hilfspunkte!
	z7=(lir,y4);
	z8=(lir,y6);
	getpen;
	draw z4{z5-z7}..{left}z5&z5{right}..{z8-z5}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(139,charwidth#,height#+2hp#,depth#);
	"The syllable NZAT";
	Plus(3wp,oben,13wp,7hp);
	Z(3wp,6hp,13wp,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZA = 
	Plus(3wp,oben,13wp,7hp);
	Zdash(3wp,6hp,13wp,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(140,charwidth#,height#+2hp#,depth#);
	"The syllable NZAX";
	eyebrow;
	NZA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(141,charwidth#,height#+2hp#,depth#);
	"The syllable NZA";
	NZA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(142,charwidth#,height#+2hp#,depth#);
	"The syllable NZAP";
	Quad(10wp,7hp,rer,1.5hp);
	z1=(13wp,8hp);
	z2=(x5,oben);
	z3=(x5,0);
	z4=(4wp,8hp);
	z5=(6.25wp,1/2[y4,y6]);
	z6=(x4,2hp);
	% Zwei Hilfspunkte!
	z7=(rer,y4);
	z8=(rer,y6);
	getpen;
	draw z1--z2--z3;
	draw z4{z5-z7}..{right}z5&z5{left}..{z8-z5}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZUO = 
	Liane(5wp,oben,11wp,8hp);
	Busen(lir,8hp,rer,6hp);
	Ih(hm,8hp,hm,0);
	X(3.5wp,4.75hp,12.5wp,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(143,charwidth#,height#+2hp#,depth#);
	"The syllable NZUOX";
	eyebrow;
	NZUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(144,charwidth#,height#+2hp#,depth#);
	"The syllable NZUO";
	NZUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZO = 
	Oh(lir,4.5hp,rer,0);
	z1=(hm,4.5hp);
	z2=(hm,8.75hp);
	z3=(13wp,7.5hp);
	z4=(x3,oben);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(145,charwidth#,height#+2hp#,depth#);
	"The syllable NZOX";
	eyebrow;
	NZO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(146,charwidth#,height#+2hp#,depth#);
	"The syllable NZOP";
	NZO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZE = 
	Plus(lir,oben,rer,7hp);
	Ih(11wp,4.5hp,11wp,1.5hp);
	z1=(rer,5.25hp);
	z2=(3wp,7hp);
	z3=(3wp,0);
	getpen;
	draw z1--z2--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(147,charwidth#,height#+2hp#,depth#);
	"The syllable NZEX";
	eyebrow;
	NZE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(148,charwidth#,height#+2hp#,depth#);
	"The syllable NZE";
	NZE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZU = 
	Plus(5wp,oben,11wp,7hp);
	Busen(lir,7hp,rer,4.5hp);
	Plus(4wp,4hp,12wp,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(149,charwidth#,height#+2hp#,depth#);
	"The syllable NZUX";
	eyebrow;
	NZU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(150,charwidth#,height#+2hp#,depth#);
	"The syllable NZU";
	NZU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(151,charwidth#,height#+2hp#,depth#);
	"The syllable NZUP";
	Plus(5wp,oben,11wp,7.5hp);
	Er(1/4width,3.75hp,3/4width,2.25hp);
	z1=(lir,8.25hp);
	z2=(5wp,7.5hp);
	z3=(hm,5.75hp);
	z4=(11wp,y2);
	z5=(rer,y1);
	z6=(hm,0);
	getpen;
	draw z1{down}..{up}z2&z2{down}..z3..{up}z4&z4{down}..{up}z5;
	draw z3--z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZUR = 
	U(lir,oben,rer,0);
	z1=(lir,8hp);
	z2=(rer,y1);
	z3=(hm,y1);	z4=(x3,0);
	getpen;
	draw z1--z2;
	draw z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(152,charwidth#,height#+2hp#,depth#);
	"The syllable NZURX";
	eyebrow;
	NZUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(153,charwidth#,height#+2hp#,depth#);
	"The syllable NZUR";
	NZUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(154,charwidth#,height#+2hp#,depth#);
	"The syllable NZYT";
	z1=(rer,oben);
	z2=(7wp,1/2[y1,y3]);
	z3=(x1,1/2[y1,y5]);
	z4=(x2,1/2[y3,y5]);
	z5=(x1,0);
	z6=(5wp,9.5hp);
		z7=(3wp,1/2[y6,y8]);
			z8=(x6,6hp);
	z9=(x6,4hp);
		z10=(x7,1/2[y9,y11]);
			z11=(x6,0.5hp);
	getpen;
	draw z1{left}..z2..{right}z3 &
		z3{left}..z4..{right}z5&z5--z1;
	draw z6..z7..z8;
	draw z9..z10..z11;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZY = 
	Ih(5wp,oben,5wp,0);
	z1=(rer,oben);
	z2=(5wp,7.5hp);
	z3=(3/4width,vm);
	z4=(x2,2.5hp);
	z5=(rer,0);
	getpen;
	draw z1--z2&z2{right}..z3..{left}z4&z4--z5;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(155,charwidth#,height#+2hp#,depth#);
	"The syllable NZYX";
	eyebrow;
	NZY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(156,charwidth#,height#+2hp#,depth#);
	"The syllable NZY";
	NZY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(157,charwidth#,height#+2hp#,depth#);
	"The syllable NZYP";
	Oh(lir,oben,rer,0);
	Brunnen(5/32width,16/24height,27/32width,4/24height);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NZYR = 
	Smiley(5.5wp,9hp,10.5wp,2hp);
	U(lir,oben,rer,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(158,charwidth#,height#+2hp#,depth#);
	"The syllable NZYRX";
	eyebrow;
	NZYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(159,charwidth#,height#+2hp#,depth#);
	"The syllable NZYR";
	NZYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(160,charwidth#,height#+2hp#,depth#);
	"The syllable NRAT";
	Oh(lir,oben,rer,0);
	z3=(lir,vm);
	z4=(rer,y3);
	z6=(hm,8hp);
	z7=(x6,6.25hp);
	z8=(x6,3.75hp);
	z9=(x6,2hp);
	getpen;
	draw z3--z4;
	draw z6--z7;
	draw z8--z9;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRA = 
	Oh(2/8width,oben,6/8width,0);
	x1=x2=x3=x4=lir;
	x5=x6=x7=x8=rer;
	y1=y5=oben-1hp;
	y4=y8=1hp;
	y2=y6=1/4[y1,y4];
	y3=y7=3/4[y1,y4];
	z9=(lir,vm);
	z10=(rer,y9);
	draw z9--z10;
	getpen;
	draw z1--z2; draw z3--z4;
	draw z5--z6; draw z7--z8;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(161,charwidth#,height#+2hp#,depth#);
	"The syllable NRAX";
	eyebrow;
	NRA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(162,charwidth#,height#+2hp#,depth#);
	"The syllable NRA";
	NRA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(163,charwidth#,height#+2hp#,depth#);
	"The syllable NRAP";
	II(5wp,oben,11wp,0);
	z1=(lir,1.5hp);
	z2=(5wp,2.75hp);
	z3=(11wp,7.25hp);
	z4=(rer,8.5hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRO = 
	Sichel(lir,oben,13wp,0);
	Plus(4wp,8hp,10wp,4hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(164,charwidth#,height#+2hp#,depth#);
	"The syllable NROX";
	eyebrow;
	NRO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(165,charwidth#,height#+2hp#,depth#);
	"The syllable NRO";
	NRO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(166,charwidth#,height#+2hp#,depth#);
	"The syllable NROP";
	Sichel(lir,8.5hp,13wp,0);
	Liane(4wp,oben,12wp,6hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(167,charwidth#,height#+2hp#,depth#);
	"The syllable NRET";
	Ih(lir,6hp,rer,6hp);
	II(3wp,4.5hp,13wp,2hp);
	z1=(13wp,oben);
	z2=(x1,7.5hp);
	z3=(hm,8.75hp);
	z4=(hm,0);
	getpen;
	draw z1--z2--z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRE = 
	z1=(4wp,vm);
	z2=(12wp,y1);
	z3=(rer,oben);
	z4=(rer,8hp);
	z5=(x2,9hp);
	z6=(x5,0);
	z13=(x1,oben);
	z14=(x13,1hp);
	z15=(lir,2hp);
	z16=(x15,0);
	getpen;
	draw z1--z2;
	draw z3--z4--z5--z6;
	draw z13--z14--z15--z16;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(168,charwidth#,height#+2hp#,depth#);
	"The syllable NREX";
	eyebrow;
	NRE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(169,charwidth#,height#+2hp#,depth#);
	"The syllable NRE";
	NRE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(170,charwidth#,height#+2hp#,depth#);
	"The syllable NREP";
	% z1 .. z5 : "d"
	z1=(13wp,8.5hp);
	z2=(9.5wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6hp);
	z6=(rer,7.5hp);
	z7=(x2,1/2[y6,y8]);
	z8=(x6,1.5hp);
	z9=(x8,y7);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
	draw z6..z7..z8;
	draw z7--z9;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(171,charwidth#,height#+2hp#,depth#);
	"The syllable NRUT";
	Oh(lir,oben,11wp,0);
	N(7wp,8.5hp,rer,5.75hp);
	N(7wp,4.25hp,rer,1.5hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRU = 
	Oh(lir,9.25hp,6.5wp,5.75hp);
	Ih(6.5wp,7.25hp,10.5wp,7.25hp);
	Oh(lir,4.25hp,6.5wp,0.75hp);
	Ih(6.5wp,2.75hp,10.5wp,2.75hp);
	z1=(14wp,oben);
	z2=(x1,8hp);
	z3=(10.5wp,10hp);
	z4=(x3,0);
	getpen;
	draw z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(172,charwidth#,height#+2hp#,depth#);
	"The syllable NRUX";
	eyebrow;
	NRU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(173,charwidth#,height#+2hp#,depth#);
	"The syllable NRU";
	NRU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(174,charwidth#,height#+2hp#,depth#);
	"The syllable NRUP";
	Liane(lir,oben,rer,6.5hp);
	Plus(lir,6hp,6.25wp,3.5hp);
	Plus(9.75wp,6hp,rer,3.5hp);
	z1=(8wp,6.5hp);
	z2=(x1,1.25hp);
	z3=(5wp,2.5hp);
	z4=(x3,0);
	getpen;
	draw z1--z2--z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRUR = 
	Oh(2wp,oben,14wp,5hp);
	z1=(hm,5hp);
	z2=(hm,1.5hp);
	z3=(lir,y2);
	getpen;
	draw z1---z2{down}..{up}z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(175,charwidth#,height#+2hp#,depth#);
	"The syllable NRURX";
	eyebrow;
	NRUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(176,charwidth#,height#+2hp#,depth#);
	"The syllable NRUR";
	NRUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(177,charwidth#,height#+2hp#,depth#);
	"The syllable NRYT";
	Xi(lir,9hp,rer,4.25hp);
	z1=(8wp,10hp);
	z2=(x1,1.25hp);
	z3=(4wp,2.5hp);
	z4=(x3,0);
	getpen;
	draw z1--z2--z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRY = 
	II(4.5wp,oben,13wp,0);
	z1=(lir,1.5hp);
	z2=(7wp,4hp);
	z3=(4.5wp,6.75hp);
	z4=(13wp,y3);
	getpen;
	draw z1--z2;
	draw z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(178,charwidth#,height#+2hp#,depth#);
	"The syllable NRYX";
	eyebrow;
	NRY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(179,charwidth#,height#+2hp#,depth#);
	"The syllable NRY";
	NRY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(180,charwidth#,height#+2hp#,depth#);
	"The syllable NRYP";
	Ih(8.5wp,oben,8.5wp,0);
	Ih(3wp,9.5hp,3wp,4.5hp);
	Ih(3wp,7hp,8.5wp,7hp);
	Ih(lir,0,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NRYR = 
	Z(lir,oben,3/4width,0);
	Oh(8.75wp,4.5hp,11.75wp,1.5hp);
	z1=(7wp,6hp);
	z2=(13wp,4.5hp);
	z3=(rer,3hp);
	getpen;
	draw z1..z2..z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(181,charwidth#,height#+2hp#,depth#);
	"The syllable NRYRX";
	eyebrow;
	NRYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(182,charwidth#,height#+2hp#,depth#);
	"The syllable NRYR";
	NRYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(183,charwidth#,height#+2hp#,depth#);
	"The syllable NJIT";
	z1=(8.5wp,oben);
	z2=(x1,1.5hp);
	z3=(lir,y2);
	z4=(rer,9hp);
	z5=(lir,1/2[y4,y6]);
	z6=(rer,5hp);
	getpen;
	draw z1---z2{down}..{up}z3;
	draw z4{left}..z5..{right}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJI = 
	Liane(2wp,oben,14wp,6hp);
	z1=(hm,oben);
	z2=(hm,1.5hp);
	z3=(lir,y2);
	getpen;
	draw z1---z2{down}..{up}z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(184,charwidth#,height#+2hp#,depth#);
	"The syllable NJIX";
	eyebrow;
	NJI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(185,charwidth#,height#+2hp#,depth#);
	"The syllable NJI";
	NJI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(186,charwidth#,height#+2hp#,depth#);
	"The syllable NJIP";
	hip:=11wp; %Hilfsliniengeber
	U(lir,oben,hip,0);
	z1=(lir,8hp);
	z2=(hip,y1);
	z3=(rer,1/2[y2,y4]);
	z4=(x2,5hp);
	getpen;
	draw z1---z2{right}..z3..{left}z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(187,charwidth#,height#+2hp#,depth#);
	"The syllable NJIET";
	Busen(lir,oben,rer,6hp);
	III(1/4width,4.25hp,3/4width,1.75hp);
	Ih(1/4width,0,3/4width,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJIE = 
	Oh(4.5wp,oben,11.5wp,0);
	N(lir,7hp,rer,3hp);
	z1=(hm,8.5hp);
	z2=(hm,6.75hp);
	z3=(hm,3.25hp);
	z4=(hm,1.5hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(188,charwidth#,height#+2hp#,depth#);
	"The syllable NJIEX";
	eyebrow;
	NJIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(189,charwidth#,height#+2hp#,depth#);
	"The syllable NJIE";
	NJIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(190,charwidth#,height#+2hp#,depth#);
	"The syllable NJIEP";
	Oh(3wp,oben,13wp,6hp);
	Ih(lir,4.5hp,rer,4.5hp);
	Ih(hm,6hp,hm,1hp);
	II(4wp,3.5hp,12wp,2.25hp);
	z1=(lir,2hp);
	z2=(hm,0);
	z3=(rer,y1);
	getpen;
	draw z1..z2..z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJUO = 
	Busen(lir,3hp,rer,0);
	z1=(4wp,4hp);
	z2=(x1,oben);
	z3=(12wp,8.5hp);
	z4=(x3,y1);
	z5=(x3,y2);
	z6=(rer,y3);
	z7=(x1,5.5hp);
	z8=(x3,y7);
	getpen;
	draw z1--z2--z3;
	draw z4--z5--z6;
	draw z7--z8;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(191,charwidth#,height#+2hp#,depth#);
	"The syllable NJUOX";
	eyebrow;
	NJUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(192,charwidth#,height#+2hp#,depth#);
	"The syllable NJUO";
	NJUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(193,charwidth#,height#+2hp#,depth#);
	"The syllable NJOT";
	IXI(lir,oben,11wp,0);
	Tdash(rer,oben,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJO = 
	IXI(lir,oben,9.5wp,0);
	z4=(12wp,9hp);
	z5=(9.75wp,1/2[y4,y6]);
	z6=(x4,1hp);
	% Zwei Hilfspunkte!
	z7=(lir,y4);
	z8=(lir,y6);
	getpen;
	draw z4{z5-z7}..{left}z5&z5{right}..{z8-z5}z6;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(194,charwidth#,height#+2hp#,depth#);
	"The syllable NJOX";
	eyebrow;
	NJO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(195,charwidth#,height#+2hp#,depth#);
	"The syllable NJO";
	NJO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(196,charwidth#,height#+2hp#,depth#);
	"The syllable NJOP";
	N(lir,7hp,rer,3hp);
	z1=(1/4width,10hp);
	z2=(11wp,vm);
	z3=(x1,0hp);
	z4=(3/4width,y1);
	z5=(5wp,vm);
	z6=(x4,y3);
	getpen;
	draw z1..z2..z3;
	draw z4..z5..z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJU = 
	Ih(4wp,vm,rer,vm);
	Ih(11wp,8.25hp,11wp,6.75hp);
	Ih(11wp,3.25hp,11wp,1.75hp);
	z1=(13wp,oben);
	z2=(4wp,vm);
	z3=(x1,0);
	getpen;
	draw z1..z2..z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(197,charwidth#,height#+2hp#,depth#);
	"The syllable NJUX";
	eyebrow;
	NJU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(198,charwidth#,height#+2hp#,depth#);
	"The syllable NJU";
	NJU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(199,charwidth#,height#+2hp#,depth#);
	"The syllable NJUP";
	Ih(4wp,vm,11wp,vm);
	z1=(13wp,oben);
	z2=(4wp,vm);
	z3=(x1,0);
	z4=(11wp,7.5hp);
	z5=(rer,vm);
	z6=(x4,2.5hp);
	getpen;
	draw z1..z2..z3;
	draw z4..z5..z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJUR = 
	Ih(5wp,7hp,14wp,7hp);
	z1=(rer,8.5hp);
	z2=(10.5wp,oben);
	z3=(x2,2hp);
	z4=(6wp,3.25hp);
	z5=(x4,0);
	z15=(7.5wp,4.5hp);
	z16=(4.25wp,1/2[y15,y17]);
	z17=(3.75wp,3hp);
	getpen;
	draw z1--z2--z3--z4--z5;
	draw z15..tension 1.2..z16..tension 1.2..z17;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(200,charwidth#,height#+2hp#,depth#);
	"The syllable NJURX";
	eyebrow;
	NJUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(201,charwidth#,height#+2hp#,depth#);
	"The syllable NJUR";
	NJUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(202,charwidth#,height#+2hp#,depth#);
	"The syllable NJYT";
	S(2wp,oben,10.5wp,0);
	Oh(10.5wp,oben,rer,6.75hp);
	Ih(2wp,3hp,2wp,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJY = 
	X(1/4width,9hp,rer,4.25hp);
	z1=(9wp,10hp);
	z2=(x1,1.5hp);
	z3=(3wp,3hp);
	z4=(x3,0);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(203,charwidth#,height#+2hp#,depth#);
	"The syllable NJYX";
	eyebrow;
	NJY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(204,charwidth#,height#+2hp#,depth#);
	"The syllable NJY";
	NJY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(205,charwidth#,height#+2hp#,depth#);
	"The syllable NJYP";
	II(1/4width,oben,3/4width,9hp);
	Z(lir,8hp,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NJYR = 
	z1=(rer,8.5hp);
	z2=(10.5wp,oben);
	z3=(x2,2hp);
	z4=(5.25wp,3.25hp);
	z5=(x4,0);
	z6=(6.5wp,9.75hp);
	z7=(x6,4.75hp);
	z8=(lir,5.75hp);
	z9=(lir,8.5hp);
	z10=(x7,7.5hp);
	getpen;
	draw z1--z2--z3--z4--z5;
	draw z6--z7--z8;
	draw z9--z10;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(206,charwidth#,height#+2hp#,depth#);
	"The syllable NJYRX";
	eyebrow;
	NJYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(207,charwidth#,height#+2hp#,depth#);
	"The syllable NJYR";
	NJYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(208,charwidth#,height#+2hp#,depth#);
	"The syllable NYIT";
	Liane(lir,oben,rer,7.25hp);
	Huegel(lir,6.25hp,rer,3.5hp);
	z1=(8wp,10hp);
	z2=(x1,1.25hp);
	z3=(4wp,2.5hp);
	z4=(x3,0);
	getpen;
	draw z1--z2--z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NYI = 
	san(lir,6.5hp,rer,2.5hp);
	z1=(rer,8hp);
	z2=(hm,oben);
	z3=(hm,0);
	getpen;
	draw z1--z2--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(209,charwidth#,height#+2hp#,depth#);
	"The syllable NYIX";
	eyebrow;
	NYI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(210,charwidth#,height#+2hp#,depth#);
	"The syllable NYI";
	NYI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(211,charwidth#,height#+2hp#,depth#);
	"The syllable NYIP";
	z1=(4wp,0);
	z2=(x1,oben);
	z3=(12wp,8hp);
	z10=(11wp,2hp);
	z11=(x10,6hp);
	getpen;
	draw z1--z2--z3;
	draw z10--z11;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(212,charwidth#,height#+2hp#,depth#);
	"The syllable NYIET";
	Liane(6wp,oben,10wp,6.75hp);
	Huegel(6wp,3.25hp,10wp,0);
	z1=(lir,oben);
	z2=(4.75wp,vm);
	z3=(lir,0);
	z4=(rer,oben);
	z5=(11.25wp,y2);
	z6=(rer,0);
	getpen;
	draw z1..z2..z3;
	draw z4..z5..z6;
	draw z2--z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NYIE = 
	Ih(8wp,oben,8wp,6.75hp);
	Huegel(6.5wp,3.25hp,10.25wp,0);
	z1=(4.5wp,oben);
	z2=(4.5wp,0);
	z3=(lir,1.5hp);
	z4=(rer,oben);
	z5=(11.25wp,vm);
	z6=(rer,0);
	getpen;
	draw z1--z2--z3;
	draw z4..z5..z6;
	draw (x2,vm)--z5;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(213,charwidth#,height#+2hp#,depth#);
	"The syllable NYIEX";
	eyebrow;
	NYIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(214,charwidth#,height#+2hp#,depth#);
	"The syllable NYIE";
	NYIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(215,charwidth#,height#+2hp#,depth#);
	"The syllable NYIEP";
	Ddash(hm,oben,hm,0);
	z1=(lir,oben);
	z2=(5wp,vm);
	z3=(lir,0);
	z4=(rer,oben);
	z5=(11wp,y2);
	z6=(rer,0);
	getpen;
	draw z1..z2..z3;
	draw z4..z5..z6;
	draw z2--z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NYUO = 
	Oh(3wp,oben,13wp,5hp);
	Ih(hm,8.15hp,hm,6.85hp);
	z1=(lir,3.75hp);
	z2=(rer,y1);
	z3=(x1,0);
	z4=(x2,y3);
	getpen;
	draw z1--z2--z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(216,charwidth#,height#+2hp#,depth#);
	"The syllable NYUOX";
	eyebrow;
	NYUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(217,charwidth#,height#+2hp#,depth#);
	"The syllable NYUO";
	NYUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(218,charwidth#,height#+2hp#,depth#);
	"The syllable NYUOP";
	Liane(5wp,oben,10.5wp,7hp);
	Liane(lir,9hp,rer,5.5hp);
	H(3wp,5hp,13wp,1.75hp);
	Ih(hm,5.5hp,hm,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(219,charwidth#,height#+2hp#,depth#);
	"The syllable NYOT";
	Ih(hm,oben,hm,0);
	z1=(lir,9hp);
	z2=(6wp,vm);
	z3=(lir,1hp);
	z4=(rer,y1);
	z5=(10wp,vm);
	z6=(rer,y3);
	getpen;
	draw z1..z2..z3;
	draw z4..z5..z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NYO = 
	Z(3wp,oben,13wp,0);
	N(lir,7.5hp,rer,5.5hp);
	N(lir,4.5hp,rer,2.5hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(220,charwidth#,height#+2hp#,depth#);
	"The syllable NYOX";
	eyebrow;
	NYO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(221,charwidth#,height#+2hp#,depth#);
	"The syllable NYO";
	NYO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(222,charwidth#,height#+2hp#,depth#);
	"The syllable NYOP";
	Arsch(lir,oben,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(223,charwidth#,height#+2hp#,depth#);
	"The syllable NYUT";
	Oh(lir,oben,rer,0);
	z1=(hm,6.25hp);
	z2=(x1,3.75hp);
	z3=(lir,vm);
	z4=(rer,y3);
	getpen;
	draw z1--z2;
	draw z3--z4;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def NYU = 
	II(4wp,oben,10.5wp,0);
	z1=(4wp,8hp);
	z2=(rer,6.25hp);
	z3=(13wp,4hp);
	z4=(13wp,2hp);
	getpen;
	draw z1--z2;
	draw z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(224,charwidth#,height#+2hp#,depth#);
	"The syllable NYUX";
	eyebrow;
	NYU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(225,charwidth#,height#+2hp#,depth#);
	"The syllable NYU";
	NYU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(226,charwidth#,height#+2hp#,depth#);
	"The syllable NYUP";
	Ih(8.5wp,oben,8.5wp,0);
	Ih(13wp,3.25hp,13wp,1.5hp);
	z4=(rer,9hp);
	z5=(lir,1/2[y4,y6]);
	z6=(rer,4.75hp);
	getpen;
	draw z4{left}..z5..{right}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(227,charwidth#,height#+2hp#,depth#);
	"The syllable PIT";
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(11wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6hp);
	z6=(3wp,4hp);
	z7=(x2,y6);
	z8=(3wp,2hp);
	z9=(x2,y8);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
	draw z6--z7;
	draw z8--z9;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PI = 
	Oh(5wp,oben,rer,0);
	z1=(lir,8.5hp);
	z2=(x1,4hp);
	z3=(rer,vm);
	getpen;
	draw z1--z2--z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(228,charwidth#,height#+2hp#,depth#);
	"The syllable PIX";
	eyebrow;
	PI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(229,charwidth#,height#+2hp#,depth#);
	"The syllable PI";
	PI;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(230,charwidth#,height#+2hp#,depth#);
	"The syllable PIP";
	X(1/4width,oben,3/4width,0);
	II(11.5wp,6.75hp,rer,3.25hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PIE = 
	Oh(lir,oben,9.25wp,0);
	Ih(lir,vm,9wp,vm);
	II(11.5wp,7.5hp,rer,2.5hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(231,charwidth#,height#+2hp#,depth#);
	"The syllable PIEX";
	eyebrow;
	PIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(232,charwidth#,height#+2hp#,depth#);
	"The syllable PIE";
	PIE;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(233,charwidth#,height#+2hp#,depth#);
	"The syllable PIEP";
	Oh(3wp,oben,13wp,5hp);
	Busen(lir,3hp,rer,0);
	Ih(hm,8.25hp,hm,6.75hp);
	Ih(hm,5hp,hm,3hp);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(234,charwidth#,height#+2hp#,depth#);
	"The syllable PAT";
	H(lir,oben,rer,0);
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PA = 
	U(lir,oben,rer,0);
	z1=(lir,6.5hp);
	z2=(rer,y1);
	z3=(hm,oben);	z4=(x3,0);
	getpen;
	draw z1--z2;
	draw z3--z4;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(235,charwidth#,height#+2hp#,depth#);
	"The syllable PAX";
	eyebrow;
	PA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(236,charwidth#,height#+2hp#,depth#);
	"The syllable PA";
	PA;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(237,charwidth#,height#+2hp#,depth#);
	"The syllable PAP";
	hip:=10wp; %Hilfsliniengeber
	U(2wp,oben,hip,0);
	x13:=hip;
	x14=x15=x16=rer;
	y13=y14=5hp;
	y15=9hp;
	y16-1/24height=1/24height;
	getpen;
	draw z13--z14; %Horizontale
	draw z15--z16; %Vertikale
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PUO = 
	II(lir,4.5hp,3/8width,2hp);
	Ih(lir,8hp,rer,8hp);
	Ih(5/8width,6hp,5/8width,0);
	Ih(7/8width,4.5hp,7/8width,2hp);
	z1=(rer,oben);
	z2=(lir,8hp);
	z3=(rer,6hp);
	getpen;
	draw z1{left}..z2..{right}z3;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(238,charwidth#,height#+2hp#,depth#);
	"The syllable PUOX";
	eyebrow;
	PUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(239,charwidth#,height#+2hp#,depth#);
	"The syllable PUO";
	PUO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(240,charwidth#,height#+2hp#,depth#);
	"The syllable PUOP";
	Plus(lir,9.8hp,rer,3.7hp);
	z1=(rer,oben);
	z2=(rer,2.5hp);
	z3=(9wp,0);
	z4=(lir,2hp);
	z5=(hm,9.8hp);
	z6=(lir,1/2[y1,y8]);
	z7=(hm,3.7hp);
	z8=(rer,3.5hp);
	getpen;
	draw z1---z2..z3..z4;
	draw z1{left}..z5..z6..z7..{right}z8;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(241,charwidth#,height#+2hp#,depth#);
	"The syllable POT";
	Otense(4wp,oben,9.5wp,0,1.4);
	Er(lir,6hp,6wp,4hp);
	z4=(12wp,9hp);
	z5=(9.75wp,1/2[y4,y6]);
	z6=(x4,1hp);
	% Zwei Hilfspunkte!
	z7=(lir,y4);
	z8=(lir,y6);
	getpen;
	draw z4{z5-z7}..{left}z5&z5{right}..{z8-z5}z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PO = 
	Liane(lir,9.5hp,rer,4.75hp);
	Ih(hm,oben,hm,4.75hp);
	Er(lir,3hp,rer,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(242,charwidth#,height#+2hp#,depth#);
	"The syllable POX";
	eyebrow;
	PO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(243,charwidth#,height#+2hp#,depth#);
	"The syllable PO";
	PO;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(244,charwidth#,height#+2hp#,depth#);
	"The syllable POP";
	Er(lir,4hp,rer,2hp);
	Ih(hm,6hp,hm,0);
	Ih(lir,8hp,rer,8hp);
	z1=(rer,oben);
	z2=(lir,8hp);
	z3=(rer,6hp);
	getpen;
	draw z1{left}..z2..{right}z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(245,charwidth#,height#+2hp#,depth#);
	"The syllable PUT";
	z1=(13wp,oben);
	z2=(x1,7hp);
	z3=(3wp,9hp);
	z4=(x3,1hp);
	z5=(x1,3hp);
	z6=(x1,0);
	getpen;
	draw z1--z2--z3--z4--z5--z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PU = 
	Ih(rer,oben,rer,0);
	z1=(hm,oben);
	z2=(lir,1/2[y1,y3]);
	z3=(x1,1/3[y1,y7]);
	z4=(x2,1/2[y3,y5]);
	z5=(x1,2/3[y1,y7]);
	z6=(x2,1/2[y5,y7]);
	z7=(x1,0);
	getpen;
	draw z1{left}..z2..{right}z3&
		z3{left}..z4..{right}z5&
			z5{left}..z6..{right}z7;
	draw z1--(rer,oben);
	draw z3--(rer,y3);
	draw z5--(rer,y5);
	draw z7--(rer,0);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(246,charwidth#,height#+2hp#,depth#);
	"The syllable PUX";
	eyebrow;
	PU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(247,charwidth#,height#+2hp#,depth#);
	"The syllable PU";
	PU;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(248,charwidth#,height#+2hp#,depth#);
	"The syllable PUP";
	Z(1/4width,oben,3/4width,0);
	Ih(5.5wp,6hp,5.5wp,4hp);
	z1=(hm,7.5hp);
	z2=(lir,vm);
	z3=(hm,2.5hp);
	getpen;
	draw z1{left}..z2..{right}z3;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PUR = 
	Oh(lir,oben,9.25wp,0);
	Ih(5.75wp,6hp,5.75wp,4hp);
	Ih(9.25wp,vm,rer,vm);
	II(11.5wp,7.5hp,rer,2.5hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(249,charwidth#,height#+2hp#,depth#);
	"The syllable PURX";
	eyebrow;
	PUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(250,charwidth#,height#+2hp#,depth#);
	"The syllable PUR";
	PUR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(251,charwidth#,height#+2hp#,depth#);
	"The syllable PYT";
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(10wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6.5hp);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PY = 
	IXI(lir,oben,rer,0);
	Ih(11.5wp,6hp,11.5wp,4hp);
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(252,charwidth#,height#+2hp#,depth#);
	"The syllable PYX";
	eyebrow;
	PY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(253,charwidth#,height#+2hp#,depth#);
	"The syllable PY";
	PY;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
beginchar(254,charwidth#,height#+2hp#,depth#);
	"The syllable PYP";
	Ih(2.5wp,7hp,8wp,7hp);
	Ih(rer,7hp,rer,3hp);
	Liane(lir,2hp,8.25wp,0);
	z1=(rer,8.5hp);
	z2=(10.5wp,oben);
	z3=(x2,0);
	z4=(x2,y1);
	z5=(5.25wp,y2);
	z6=(x5,2hp);
	getpen;
	draw z1--z2--z3;
	draw z4--z5--z6;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
def PYR = 
	% z1 .. z5 : "d"
	z1=(rer,8.5hp);
	z2=(10wp,oben);
	z3=(x2,0);
	z4=(lir,1/2[y5,0]);
	z5=(x2,6hp);
	z6=(1/4width,oben);
	z7=(x6,7.5hp);
	z8=(rer,y5);
	z9=(x8,3hp);
	getpen;
	draw z1--z2--z3;
	draw z3{left}..z4..{right}z5;
	draw z6--z7;
	draw z8--z9;
enddef;
% % % % % % % % % % % % % % % % % % % % % % % % % % % % % % % %
beginchar(255,charwidth#,height#+2hp#,depth#);
	"The syllable PYRX";
	eyebrow;
	PYR;
endchar;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
end.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%% The Yi Syllable Font, Part III, ends here. %%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%